Binding QML 類型

使能夠創建任意特性綁定。更多...

import 語句：

import QtQml 2.12

所有成員列錶，包括繼承成員

特性

delayed : bool
property : string
target : Object
value : any
when : bool

詳細描述

在 QML 中，特性綁定會導緻不同對象特性之間的依賴。

綁定到不可訪問特性

Sometimes it is necessary to bind an object's property to that of another object that isn't directly instantiated by QML, such as a property of a class exported to QML by C++. You can use the Binding type to establish this dependency; binding any value to any object's property.

For example, in a C++ application that maps an "app.enteredText" property into QML, you can use Binding to update the enteredText property.

TextEdit { id: myTextField; text: "Please type here..." }
Binding { target: app; property: "enteredText"; value: myTextField.text }

當 text 變化，C++ 特性 enteredText 會自動更新。

條件綁定

In some cases you may want to modify the value of a property when a certain condition is met but leave it unmodified otherwise. Often, it's not possible to do this with direct bindings, as you have to supply values for all possible branches.

For example, the code snippet below results in a warning whenever you release the mouse. This is because the value of the binding is undefined when the mouse isn't pressed.

// produces warning: "Unable to assign [undefined] to double value"
value: if (mouse.pressed) mouse.mouseX

Binding 類型可以阻止此警告。

Binding on value {
    when: mouse.pressed
    value: mouse.mouseX
}

The Binding type restores any previously set direct bindings on the property.

另請參閱 Qt QML .

特性文檔編製

delayed : bool

此特性保持 Binding 是否應延遲。

A delayed binding will not immediately update the target, but rather wait until the event queue has been cleared. This can be used as an optimization, or to prevent intermediary values from being assigned.

Binding {
    target: contactName; property: 'text'
    value: givenName + " " + familyName; when: list.ListView.isCurrentItem
    delayed: true
}

該特性在 Qt 5.8 引入。

property : string

要更新的特性。

This can be a group property if the expression results in accessing a property of a 值類型。例如：

Item {
    id: item
    property rect rectangle: Qt.rect(0, 0, 200, 200)
}
Binding {
    target: item
    property: "rectangle.x"
    value: 100
}

target : 對象

要更新的對象。

value : any

The value to be set on the target object and property. This can be a constant (which isn't very useful), or a bound expression.

當 : bool

This property holds when the binding is active. This should be set to an expression that evaluates to true when you want the binding to be active.

Binding {
    target: contactName; property: 'text'
    value: name; when: list.ListView.isCurrentItem
}

When the binding becomes inactive again, any direct bindings that were previously set on the property will be restored.